#################################################
#
#  (C) 2021 Slávek Banko
#  slavek.banko (AT) axis.cz
#
#  Improvements and feedback are welcome
#
#  This file is released under GPL >= 2
#
#################################################


##### set project version ########################

include( TDEVersion )
cmake_minimum_required( VERSION ${TDE_CMAKE_MINIMUM_VERSION} )
tde_set_project_version( )


##### general package setup #####################

project( tde-i18n )


##### include essential cmake modules ###########

include( FindPkgConfig ) # required for find_package( TDE )


##### include our cmake modules #################

include( TDEMacros )


##### find required stuff #######################

find_package( TDE )

include( TDESetupPaths )
tde_setup_paths( )


##### process languages #########################

file( GLOB _dirs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} * )
list( SORT _dirs )

string( REGEX REPLACE "[ \r\n\t]+" ";" _linguas "$ENV{LINGUAS}" )

foreach( _dir IN LISTS _dirs )
  string( REGEX REPLACE "^${PROJECT_NAME}-" "" _lang "${_dir}" )
  if( "${_dir}" MATCHES "^${PROJECT_NAME}-"
      AND IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/${_dir}
      AND EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${_dir}/CMakeLists.txt
      AND ( "${_lang}" STREQUAL "en" OR
            "${_linguas}" MATCHES "^;*$" OR
            ";${_linguas};" MATCHES ";${_lang};" ))
    add_subdirectory( ${_dir} )
    string( REGEX REPLACE "@" "_" _lang_target "${_lang}" )
    add_custom_target( install-${_lang_target}
      COMMAND ${CMAKE_COMMAND}
        -DCOMPONENT=${_lang}
        -P ${CMAKE_BINARY_DIR}/cmake_install.cmake
    )
  endif()
endforeach()
